Ansichtkarten Script

vkyr
Beiträge: 44
Registriert: Mi 27. Feb 2013, 16:38
Skype:
Kontaktdaten:

Ansichtkarten Script

Beitragvon vkyr » Do 28. Feb 2013, 14:10

Hallo Allerseits,

vor geraumer Zeit gab es einmal in der c't special Digitale Fotografie - Ausgabe 04/10 einen Artikel zur Erstellung eines druckbaren Ansichtkartenlayout (Querformat: 170 x 120 mm bei 300 pixel/inch) mittels Gimp. Im Internet kann man sich hierzu auch ein entsprechend gut zusammengefasstes Tutorial durchlesen, siehe:


Da ich des öfteren mal eigene Foto-Ansichtkarten für das Ausdrucken nach der Methode im oben genannten Artikel/Tutorial erstelle, war es auf Dauer irgendwie lästig immer wieder quasi die gleichen Schritte von neuem manuell in Gimp durchzuführen. Kurzum eine Automatisierung in Form eines Skriptes musste her. Das weiter unten aufgeführte Script ansichtskarte.scm ist das Resultat.

Wichtige Anmerkungen zum Script und etwaige Abweichungen vom c't Ursprungsartikel

  1. Ich empfehle vor der Verwendung des Scriptes, sich zuvor einmal das oben referenzierte online Tutorial durchzulesen, damit man einen Einblick davon bekommt was das Script überhaupt tut!
  2. Das Script ist in seiner aktuellen Form lediglich für die Erzeugung einer 170 x 120 mm (bei 300 pixel/inch) Ansichtskarte im Querformat ausgelegt! Wer ein anderes Ausgabeformat wünscht, sprich Hochformat oder eine andere Ausgabegrösse etc., sollte sich somit nicht auf die setzbaren Parameter des Scriptes blind verlassen, denn u.U. muss der Scriptcode zuvor erst den individuellen Wünschen angepasst werden.
  3. Das Script skaliert ein zuvor in Gimp geladenes Ausgangsbild/Foto -entgegen dem Tutorial- proportional unter Beibehaltung des Seitenverhältnisses (Aspect Ratio). Sprich das Ausgangsbild wird lediglich proportional skaliert auf etwa 136 x ~80 mm bei 300 pixel/inch.
  4. WICHTIG: die von dem Script erzeugten Ebenen (Layer) werden am Ende seiner Ausführung bewußt nicht zu einer einzigen Ebene zusammengefasst. So bleibt gewährleistet das man nach der Abarbeitung des Skriptes noch etwas Feintuning an der Ausrichtung-/Platzierung der einzelnen Ebenen wie der des inneres Fotos, des schmalen inneren Rahmen, der Untertitel-Textebene und dem Schlagschatten für den Text etc. vornehmen kann!

Der Code des ansichtskarte.scm Script:

Code: Alles auswählen

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
; SCRIPT-FU-ANSICHTSKARTE
; nach c't special Digitale Fotografie Okt-Dez 2010
;
; version 1.01  2013.02.14 Deutsch
; Copyright (c) 2013 Valentino Kyriakides
;

  (define (script-fu-ansichtskarte image the-drawable cwidth cheight cdpi ccolor image-width
           image-height use-frame frame-color in-text in-font in-font-size in-text-color use-drop-shadow)
    (let* (
            ; Lokale Variablen
            (card-width cwidth)
            (card-height cheight)
            (dpi cdpi)
            (card-color ccolor)
            (img (car (gimp-drawable-get-image the-drawable)))
            (img-layer 0)
            (card-layer 0)
            (text-layer 0)
            (text-width 0)
            (text-height 0)
            (text-posX 0)
            (text-posY 0)
          )   
               
     
      ; Konvertiert mm in pixel für spezifische dpi
      (define (mm-to-pixel-for-dpi dpi mm)
         (round (* mm (/ dpi 25.4)))
      )
     
      ; Skaliert ein Bild unter beibehaltung der Ratio
      (define (resize-image-keep-ratio image new-width new-height)
        (let* (
               (drawable   (car (gimp-image-active-drawable image)))
               (cur-width  (car (gimp-image-width image)))
               (cur-height (car (gimp-image-height image)))
               (ratio      (min (/ new-width cur-width) (/ new-height cur-height)))
               (width      (* ratio cur-width))
               (height     (* ratio cur-height))
              )

              (gimp-image-scale image width height)
        )
      )     
     
      ; Erzeugt eine Ansichtskartenebene
      (define (make-card-layer image pwidth pheight pcolor)
        (let* ((layer (car (gimp-layer-new image pwidth pheight
                        RGB-IMAGE "card-layer" 100 NORMAL-MODE))))
         (gimp-context-set-foreground pcolor)
         (gimp-drawable-fill layer FG-IMAGE-FILL)
         (gimp-image-add-layer image layer 0)
      ))
     
      ;;;;;;; Hauptprogrammteil ;;;;;;;;;;;
     
      (gimp-context-push)
      (gimp-image-undo-group-start img)
     
      ; Das Foto skalieren 
      (resize-image-keep-ratio img
        (mm-to-pixel-for-dpi dpi image-width) 
        (mm-to-pixel-for-dpi dpi image-height))
      (gimp-image-set-resolution img dpi dpi)
      (set! img-layer (car (gimp-image-get-active-layer img)))
     
      ; Rahmen um das Foto
      (if (= use-frame TRUE)
        (script-fu-addborder img the-drawable 7 7 frame-color 20)
      )
     
      ; Bildgrösse und Positionierung
      (gimp-image-resize img
        (mm-to-pixel-for-dpi dpi card-width) 
        (mm-to-pixel-for-dpi dpi card-height)
          286 200)
     
      ; Kartenebene in Farbe erstellen
      (make-card-layer img 
        (mm-to-pixel-for-dpi dpi card-width) 
        (mm-to-pixel-for-dpi dpi card-height)
        card-color)
      (set! card-layer (car (gimp-image-get-active-layer img)))
      (gimp-image-lower-item-to-bottom img card-layer)
     
      ; Untertitel Textlayer erstellen und positionieren
      (gimp-context-set-foreground in-text-color)
      (set! text-layer (car
                                (gimp-text-fontname
                                img -1
                                0 0
                                in-text
                                0
                                TRUE
                                in-font-size PIXELS
                                in-font)
                          ))
      (gimp-text-layer-set-letter-spacing text-layer 57)
      (set! text-width (car (gimp-drawable-width text-layer)))
      (set! text-height (car (gimp-drawable-height text-layer)))
      (set! text-posX (/ (- (mm-to-pixel-for-dpi dpi card-width) text-width) 2))
      (set! text-posY (/ (- (mm-to-pixel-for-dpi dpi card-height) text-height) 2))     
      (gimp-layer-set-offsets text-layer text-posX (+ text-posY 500))
      (gimp-image-raise-item-to-top img text-layer)
           
      ; Schlagschatten für den Untertitel-Text erstellen
      (if (= use-drop-shadow TRUE)
        (script-fu-drop-shadow img text-layer 5 5 15 '(0 0 0) 64 0)
      )
     
      (gimp-displays-flush)
      (gimp-image-undo-group-end img)
      (gimp-context-pop)
    )
  )
 
  (script-fu-register
            "script-fu-ansichtskarte"                   
            "Ansichtskarte"                                 
            "Erstellt aus einem Foto eine 300 DPI, 170 x 120 mm Ansichtskarte, mit Rahmen und Bilduntertitel."             
            "Valentino Kyriakides"                     
            "(C) 2013, Valentino Kyriakides, by KyrSoft"                           
            "Februar 14, 2013"                                           
            "*"                                         
            SF-IMAGE       "Image" 0
            SF-DRAWABLE    "Drawable" 0
            SF-VALUE       "Kartenbreite [mm]"  "170"       
            SF-VALUE       "Kartenhoehe [mm]" "120"       
            SF-VALUE       "Pixel/inch"  "300"       
            SF-COLOR       "Farbe der Aussenflaeche"  '(255 255 255)   
            SF-VALUE       "Breite eingebetetes Foto [mm]" "136"   
            SF-VALUE       "Hoehe eingebetetes Foto [mm]" "80"               
            SF-TOGGLE      "Rahmen um Foto" TRUE     
            SF-COLOR       "Rahmenfarbe"  '(78 78 78)         
            SF-STRING      "Fotountertitel" "Untertitel"     
            SF-FONT        "Schriftart"      "Trebuchet MS"   
            SF-ADJUSTMENT  "Schriftgroesse"   '(59 1 1000 1 10 0 1)   
            SF-COLOR       "Schriftfarbe"    '(78 78 78)     
            SF-TOGGLE      "Schlagschatten" TRUE   
  )
  (script-fu-menu-register "script-fu-ansichtskarte" "<Image>/Filters/Decor")




Erweiterungsmöglichkeiten des Script für Interessierte

  • Da das Script in seinem aktuellen Zustand keinerlei Eingabe-Validierungen vornimmt, wäre es denkbar soetwas zusätzlich einzubauen. Z.B. eine interne Prüfung das bei Grössenangaben die angegebene innere Bildgrösse immer kleiner sein muss als die Gesamtkartengrösse der Karte usw.
  • Noch zusätzlich einen weiteren schmalen 2-3 Pixel grossen Rahmen um den äußeren Bereich der Karte in einer gewünschten Farbe erzeugen lassen.
  • Auch ein Hochformat für Karten zu berücksichtigen und somit im Code und bei den Optionen dann zwischen Hoch- und Querformat zu unterscheiden.
  • Vieles andere an das ich so auf die Schnelle nicht gedacht habe ...


Viel Spaß bei der Gestaltung von tollen Ansichtskarten wünscht

vkyr

(Ergänzend eingefügt von do-se: Vorschaubild und fertiges, überarbeitetes script) ;)
Bild

Ansichtskarte.zip
(1.87 KiB) 362-mal heruntergeladen

Benutzeravatar
do-se
Beiträge: 4700
Registriert: Mi 7. Apr 2010, 19:48
Skype:
Wohnort: bei München
Kontaktdaten:

Re: Ansichtkarten Script

Beitragvon do-se » Do 28. Feb 2013, 15:09

:freu:

Klasse, ich habe es gleich mal ausprobiert.
Allerdings wird mein Foto nicht in die Mitte der Karte plaziert. :think:
Hier mal ein extremes Beispiel:

#

Zur Not kann man die Fotoebene natürlich von Hand nachschieben.
#
Galerie alt und Galerie neu
Hier gibt es unsere selbstgebastelten Smileys
Bild

Benutzeravatar
Arran
Beiträge: 1845
Registriert: Di 6. Apr 2010, 14:41
Skype:
Wohnort: Corriecravie, Isle of Arran, Scotland
Kontaktdaten:

Re: Ansichtkarten Script

Beitragvon Arran » Do 28. Feb 2013, 15:16

Interessant, nur wieso hast Du nicht das international anerkannte und weit verbreitete Format 150 x 100 gesetzt, von dem von praktisch allen Fotopapierhersteller Pakete erhältlich sind?

Abgesehen davon mache ich alle Ansichtskarten auf A4 und schneide sie dann mit der Guillotine zu. Kommt erheblich billiger, da man für den Preis eines A4 Fotopapiers in gleicher Qualität nur etwa 1.8 kleinere Karten bekommt.

Mein Vorschlag: Beide Varianten noch einbauen: einmal die von 150x100 (randlos) und einmal die mit 4 A6-Felder auf einem randlosen A4. Dabei sollte je nach Wunsch mit einem Bild vierfach, mit zwei Bilder doppelt oder mit 4 Bildern einfach gedrucht werden können.

Reizt es Dich, diese Erweiterung noch einzubauen?

Die Hochstellmöglichkeit finde ich nicht unbedingt nötig, denn mittels Gimp kann man das Bild ja problemlos 90° quergedreht erstellen. Oder wenn es fertig ist drehen und schon hat man es richtig.
Grüsse von Schottlands schönster Ferieninsel: Isle of ArranBild
Kubuntu 14.04.5, HP ZR30w 2600 x 1600 px, Gimp 2.8.?

Arrans Galerie
Meine Desktop-Hintergründe

vkyr
Beiträge: 44
Registriert: Mi 27. Feb 2013, 16:38
Skype:
Kontaktdaten:

Re: Ansichtkarten Script

Beitragvon vkyr » Do 28. Feb 2013, 16:52

do-se hat geschrieben::freu:

Klasse, ich habe es gleich mal ausprobiert.
Allerdings wird mein Foto nicht in die Mitte der Karte plaziert. :think:
Hier mal ein extremes Beispiel:

#

Zur Not kann man die Fotoebene natürlich von Hand nachschieben.


Sieht so aus als wenn Du eine andere Kartenbreite als die bis dato vorgesehenen 170 mm verwendet hast, denn bei 170 mm wäre das Bild im Verhältnis zentrierter. Der Script-Code benutzt z.T. nur feste Offset-Werte für die Ausrichtung des initialen Bildes, sprich das innere Bild wird nicht wirklich zentriert platziert. Lediglich der Untertitel wird aktuell quasi zentriert berechnet und platziert.
Kann man aber auch für das innere Bild im Code anpassen!

vkyr
Beiträge: 44
Registriert: Mi 27. Feb 2013, 16:38
Skype:
Kontaktdaten:

Re: Ansichtkarten Script

Beitragvon vkyr » Do 28. Feb 2013, 17:19

Arran hat geschrieben:Interessant, nur wieso hast Du nicht das international anerkannte und weit verbreitete Format 150 x 100 gesetzt, von dem von praktisch allen Fotopapierhersteller Pakete erhältlich sind?

Abgesehen davon mache ich alle Ansichtskarten auf A4 und schneide sie dann mit der Guillotine zu. Kommt erheblich billiger, da man für den Preis eines A4 Fotopapiers in gleicher Qualität nur etwa 1.8 kleinere Karten bekommt.

Mein Vorschlag: Beide Varianten noch einbauen: einmal die von 150x100 (randlos) und einmal die mit 4 A6-Felder auf einem randlosen A4. Dabei sollte je nach Wunsch mit einem Bild vierfach, mit zwei Bilder doppelt oder mit 4 Bildern einfach gedrucht werden können.

Reizt es Dich, diese Erweiterung noch einzubauen?

Die Hochstellmöglichkeit finde ich nicht unbedingt nötig, denn mittels Gimp kann man das Bild ja problemlos 90° quergedreht erstellen. Oder wenn es fertig ist drehen und schon hat man es richtig.


Mir persönlich ging es in erster Linie nur um die im Artikel erwähnte feste 170x120 mm Kartengröße, sprich sämtliche Eventualitäten wollte ich mit dem Script gar nicht abdecken und habe mich daher auch mehr an besagte Vorgaben aus dem Artikel gehalten. Andere Formate wie das 150 x 100 mm Postformat etc. sollten für jeden der es brauch leicht im Script anpassbar sein.

Was A4 Bögen betrifft, das könnte man zwar alles machen und implementieren, aber ich persönlich drucke Karten, Fotos etc. nicht direkt aus Gimp heraus, da mir dieses teilweise viel zu ungenau ist. Ich bereite diese stattdessen nur mehr optisch in Gimp vor und verwende andere Layoutwerkzeuge für den Druck. - Somit halten sich auch meine Ambitionen in Grenzen das Script komplett dahingehend umzubauen. - Aber jeder der mag kann sich das so ausbauen wie er möchte!

Benutzeravatar
do-se
Beiträge: 4700
Registriert: Mi 7. Apr 2010, 19:48
Skype:
Wohnort: bei München
Kontaktdaten:

Re: Ansichtkarten Script

Beitragvon do-se » Do 28. Feb 2013, 17:27

:shifty:
Ich habe das Script erst einmal ohne irgendwelchen Änderungen laufen lassen und gesehen, dass es nicht in der Mitte ist.
Vielleicht ist mein Fotoformat falsch.

....Kann man aber auch für das innere Bild im Code anpassen!

Dann geh ich mal suchen. ;)
#
Galerie alt und Galerie neu
Hier gibt es unsere selbstgebastelten Smileys
Bild

vkyr
Beiträge: 44
Registriert: Mi 27. Feb 2013, 16:38
Skype:
Kontaktdaten:

Re: Ansichtkarten Script

Beitragvon vkyr » Do 28. Feb 2013, 18:53

do-se hat geschrieben::shifty:
Ich habe das Script erst einmal ohne irgendwelchen Änderungen laufen lassen und gesehen, dass es nicht in der Mitte ist.
Vielleicht ist mein Fotoformat falsch.

....Kann man aber auch für das innere Bild im Code anpassen!

Dann geh ich mal suchen. ;)


Möglich dass das Seitenverhältnis kein typisches 3:2 oder ähnlich war, es mag aber auch am Script gelegen haben. Wie dem auch sei, ich habe hier einmal die Zentrierung/Ausrichtung für das mittlere Bild nachträglich eingebaut. D.h. nun sollten die inneren Bilder eigentlich zentriert angezeigt werden mit einem kleinen Y-Versatz nach oben hin von 30 Pixeln um Platz für den Untertitel zu lassen!

Überarbeitete Ansichtskarten Script - Version 1.02, Änderung automatische Bildzentrierung:

Code: Alles auswählen

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
; SCRIPT-FU-ANSICHTSKARTE
; nach c't special Digitale Fotografie Okt-Dez 2010
;
; version 1.02  2013.02.14 Deutsch
; Copyright (c) 2013 Valentino Kyriakides
;

  (define (script-fu-ansichtskarte image the-drawable cwidth cheight cdpi ccolor image-width
           image-height use-frame frame-color in-text in-font in-font-size in-text-color use-drop-shadow)
    (let* (
            ; Lokale Variablen
            (card-width cwidth)
            (card-height cheight)
            (dpi cdpi)
            (card-color ccolor)
            (img (car (gimp-drawable-get-image the-drawable)))
            (img-layer 0)
            (card-layer 0)
            (text-layer 0)
            (text-width 0)
            (text-height 0)
            (text-posX 0)
            (text-posY 0)
            (img-width 0)
            (img-height 0)
            (img-posX 0)
            (img-posY 0)
          )   
               
     
      ; Konvertiert mm in pixel für spezifische dpi
      (define (mm-to-pixel-for-dpi dpi mm)
         (round (* mm (/ dpi 25.4)))
      )
     
      ; Skaliert ein Bild unter beibehaltung der Ratio
      (define (resize-image-keep-ratio image new-width new-height)
        (let* (
               (drawable   (car (gimp-image-active-drawable image)))
               (cur-width  (car (gimp-image-width image)))
               (cur-height (car (gimp-image-height image)))
               (ratio      (min (/ new-width cur-width) (/ new-height cur-height)))
               (width      (* ratio cur-width))
               (height     (* ratio cur-height))
              )

              (gimp-image-scale image width height)
        )
      )     
     
      ; Erzeugt eine Ansichtskartenebene
      (define (make-card-layer image pwidth pheight pcolor)
        (let* ((layer (car (gimp-layer-new image pwidth pheight
                        RGB-IMAGE "card-layer" 100 NORMAL-MODE))))
         (gimp-context-set-foreground pcolor)
         (gimp-drawable-fill layer FG-IMAGE-FILL)
         (gimp-image-add-layer image layer 0)
      ))
     
      ;;;;;;; Hauptprogrammteil ;;;;;;;;;;;
     
      (gimp-context-push)
      (gimp-image-undo-group-start img)
     
      ; Das Foto skalieren 
      (resize-image-keep-ratio img
        (mm-to-pixel-for-dpi dpi image-width) 
        (mm-to-pixel-for-dpi dpi image-height))
      (gimp-image-set-resolution img dpi dpi)
      (set! img-layer (car (gimp-image-get-active-layer img)))
     
      ; Rahmen um das Foto
      (if (= use-frame TRUE)
        (script-fu-addborder img the-drawable 7 7 frame-color 20)
      )
     
      ; Bildgrösse und Positionierung
      (set! img-width (car (gimp-image-width img)))
      (set! img-height (car (gimp-image-height img)))
      (set! img-posX (/ (- (mm-to-pixel-for-dpi dpi card-width) img-width) 2))
      (set! img-posY (/ (- (mm-to-pixel-for-dpi dpi card-height) img-height) 2))     
      (gimp-image-resize img
        (mm-to-pixel-for-dpi dpi card-width) 
        (mm-to-pixel-for-dpi dpi card-height)
          img-posX (- img-posY 30))
     
      ; Kartenebene in Farbe erstellen
      (make-card-layer img 
        (mm-to-pixel-for-dpi dpi card-width) 
        (mm-to-pixel-for-dpi dpi card-height)
        card-color)
      (set! card-layer (car (gimp-image-get-active-layer img)))
      (gimp-image-lower-item-to-bottom img card-layer)
     
      ; Untertitel Textlayer erstellen und positioniren
      (gimp-context-set-foreground in-text-color)
      (set! text-layer (car
                                (gimp-text-fontname
                                img -1
                                0 0
                                in-text
                                0
                                TRUE
                                in-font-size PIXELS
                                in-font)
                          ))
      (gimp-text-layer-set-letter-spacing text-layer 57)
      (set! text-width (car (gimp-drawable-width text-layer)))
      (set! text-height (car (gimp-drawable-height text-layer)))
      (set! text-posX (/ (- (mm-to-pixel-for-dpi dpi card-width) text-width) 2))
      (set! text-posY (/ (- (mm-to-pixel-for-dpi dpi card-height) text-height) 2))     
      (gimp-layer-set-offsets text-layer text-posX (+ text-posY 500))
      (gimp-image-raise-item-to-top img text-layer)
           
      ; Schlagschatten für den Untertitel-Text erstellen
      (if (= use-drop-shadow TRUE)
        (script-fu-drop-shadow img text-layer 5 5 15 '(0 0 0) 64 0)
      )
     
      (gimp-displays-flush)
      (gimp-image-undo-group-end img)
      (gimp-context-pop)
    )
  )
 
  (script-fu-register
            "script-fu-ansichtskarte"                   
            "Ansichtskarte"                                 
            "Erstellt aus einem Foto eine 300 DPI, 170 x 120 mm Ansichtskarte, mit Rahmen und Bilduntertitel."             
            "Valentino Kyriakides"                     
            "(C) 2013, Valentino Kyriakides, by KyrSoft"                           
            "Februar 14, 2013"                                           
            "*"                                         
            SF-IMAGE       "Image" 0
            SF-DRAWABLE    "Drawable" 0
            SF-VALUE       "Kartenbreite [mm]"  "170"       
            SF-VALUE       "Kartenhoehe [mm]" "120"       
            SF-VALUE       "Pixel/inch"  "300"       
            SF-COLOR       "Farbe der Aussenflaeche"  '(255 255 255)   
            SF-VALUE       "Breite eingebetetes Foto [mm]" "136"   
            SF-VALUE       "Hoehe eingebetetes Foto [mm]" "80"               
            SF-TOGGLE      "Rahmen um Foto" TRUE     
            SF-COLOR       "Rahmenfarbe"  '(78 78 78)         
            SF-STRING      "Fotountertitel" "Untertitel"     
            SF-FONT        "Schriftart"      "Trebuchet MS"   
            SF-ADJUSTMENT  "Schriftgroesse"   '(59 1 1000 1 10 0 1)   
            SF-COLOR       "Schriftfarbe"    '(78 78 78)     
            SF-TOGGLE      "Schlagschatten" TRUE   
  )
  (script-fu-menu-register "script-fu-ansichtskarte" "<Image>/Filters/Decor")



Ach ja, wer statt der vorgegebenen 170 x 120 mm Kartengröße lieber 150 x 100 mm oder dergleichen erstellen lassen möchte, der Überschreibe einfach die Parameter im Optionen-Fenster des Skriptes. Man muss nur darauf achten das die Größenangaben des eingebetteten Bildes halt kleiner angegeben werden als die Kartengröße.

Also z.B. für 150 x 100 mm dann:

Kartenbreite [mm] = 150
Kartenhoehe [mm] = 100
Pixel/inch = 300
...
Breite eingebetetes Foto [mm] = 116
Hoehe eingebetetes Foto [mm] = 60
...
etc.

Benutzeravatar
Arran
Beiträge: 1845
Registriert: Di 6. Apr 2010, 14:41
Skype:
Wohnort: Corriecravie, Isle of Arran, Scotland
Kontaktdaten:

Re: Ansichtkarten Script

Beitragvon Arran » Do 28. Feb 2013, 19:18

vkyr hat geschrieben:... ich persönlich drucke Karten, Fotos etc. nicht direkt aus Gimp heraus, da mir dieses teilweise viel zu ungenau ist. Ich bereite diese stattdessen nur mehr optisch in Gimp vor und verwende andere Layoutwerkzeuge für den Druck ...


Ich schiesse mich da an. Solche Fotozusammenstellungen mache ich seit neuestem mit Scribus, früher mit Writer.
Grüsse von Schottlands schönster Ferieninsel: Isle of ArranBild
Kubuntu 14.04.5, HP ZR30w 2600 x 1600 px, Gimp 2.8.?

Arrans Galerie
Meine Desktop-Hintergründe

Benutzeravatar
do-se
Beiträge: 4700
Registriert: Mi 7. Apr 2010, 19:48
Skype:
Wohnort: bei München
Kontaktdaten:

Re: Ansichtkarten Script

Beitragvon do-se » Fr 1. Mär 2013, 19:38

Hallo vkyr

:hops: Jetzt klappt es.
Danke das du es gerichtet hast.
Es hat mir viel Kopfzerbrechen erspart und ich kann mal das alte mit dem neuen Script vergleichen.
:dank: Für dieses schöne script.
#
Galerie alt und Galerie neu
Hier gibt es unsere selbstgebastelten Smileys
Bild

vkyr
Beiträge: 44
Registriert: Mi 27. Feb 2013, 16:38
Skype:
Kontaktdaten:

Re: Ansichtkarten Script

Beitragvon vkyr » So 3. Mär 2013, 15:46

Hallo do-se,

na ja viel hat sich dafür im Script nicht geändert, es werden jetzt lediglich die X- und Y-Position für eine zentrierte Positionierung des innere Bildes zuvor kurz berechnet ...

  • Bild X-Position = (Kartenbreite - Bildbreite) / 2
  • Bild Y-Position = (Kartenhöhe - Bildhöhe) / 2

... und die resultierenden beiden x/y-Werte dann der (gimp-image-resize) Funktion als x/y-offset Parameter übergeben. Dadurch zentriert sich dann das innere Bild bei seiner Größenänderung bzw. es wird zentriert angezeigt.

Gruss vkyr


Zurück zu „Scripte und Filter/Plugins“



Wer ist online?

Mitglieder in diesem Forum: 0 Mitglieder und 3 Gäste